博文
AGN宽线区光度计算（IDL程序）
|||
Function broadlinelum_c97, Flux_line, z, Lum_line0, select=select, $
H0=H0, k=k, Lambda0=Lambda0, Omega_m=Omega_m, q0=q0, Silent = silent
;+
;NAME:
; broadlinelum_c97
;PURPOSE:
; compute broad line region luminosity from emissionline flux
; by Celotti 1997 method
;CALLING SEQUENCE:
; result=broadlinelum_c97(Flux_line, z, select=select)
;INPUT:
; Flux_line ---- broad emission line flux in Unit:erg/s/cm^2
; z ---- redshift
;OPTIONAL KEYWORD INPUT:
; select ----- emission line select
; 1: H_Beta emission line
; 2: Mg II emission line
; 3: C VI emission line
; 4: H_Alpha emission line
; H0 --- Hubble parameter in km/s/Mpc, default is 70
;
; No more than two of the following four parameters should be
; specified.
; None of them need be specified -- the adopted defaults are given.
;
; k --- curvature constant, normalized to the closure density.
; Default is 0, indicating a flat universe
; Omega_m ---- Matter density, normalized to the closure density,
; default is 0.3. Must be non-negative
; Lambda0 ---- Cosmological constant, normalized to the closure
; density,default is 0.7
; q0 --- Deceleration parameter,
; numeric scalar = -R*(R'')/(R')^2,
; default is -0.5
;METHOD:
; see Celotti, A.; Padovani, P.; Ghisellini, G.
; 1997 MNRAS 286. 415C
; 'Jets and accretion processes in active galactic nuclei: further
; clues'
;
;REVISION HISTORY:
; Original by DL.Wang,Oct-23-2007,Tue
;-
cosmo_param,Omega_m,Lambda0,k,q0
if N_elements(H0) EQ 0 then H0 = 70
if not keyword_set(silent) then $
print,'LUMDIST: H0:', h0, ' Omega_m:', omega_m, ' Lambda0',lambda0, $
' q0: ',q0, ' k: ', k, f='(A,I3,A,f5.2,A,f5.2,A,f5.2,A,F5.2)'
dL=lumdist(z,H0=H0,k=k,Omega_m=Omega_m,Lambda0=Lambda0,q0=q0)
factor=3.085678D+24
dL0=dL*factor ;transform Mpc to cm
Lum_line0=4.0*!DPI*dL0*dL0*Flux_line ;erg/s
if not keyword_set(select) then begin
print,''
print,'Emission line select:'
print,''
print,'========================================'
print,' H_Beta emission line : 1 '
print,' Mg II emission line : 2 '
print,' C VI emission line : 3 '
print,' H_Alpha emission line : 4 '
print,'========================================'
read,select
endif
case select of
1:c0=25.26
2:c0=16.35
3:c0=8.82
4:c0=7.22
endcase
Lum_broadline=Lum_line0*c0
return,Lum_broadline
End
https://blog.sciencenet.cn/blog-456360-658880.html
上一篇：同波段不同波长范围的能谱指数转化（IDL程序）
下一篇：改正因子计算（IDL程序）
